字串中文的问题

字串中文的问题，起於vb的字串是使用UniCode，而我们一般是使用Ascii Code。
这差别在何处呢？UniCode的每个字元长度是2个byte，而Ascii是一个byte，如果
说，我将们将VB的字串写入档案，有时会有意想不到的结果。例如：
  Text1.Text = "这是一个abc"
  len5 = Len(str5)
如果我们的Access资料库有一栏位的长度是10个Byte，所以我们在TextBox中设定
MaxLength = 10，但是上面的例子得到的len5是7，而不是我们认为的11，因为不管
是中文或英文，vb一律以UniCode来存，所以str5的长度是7个"字元"，而text1最大
的长度限制是10，7没有超过10，故使用者仍可输入，但存档时，11个byte超过10个
byte，所以会有错。

可是或许有人发现，使用RS232来传资料时，另一端主机是Ascii编码的机器，在vb中
我们若使用String来传，一样可以通啊，其实那是vb在传送与接收data时，会做转换
，使我们的程式设计较方便，但如果传的资料是Binary时，就头大啦。例如说，以字
串的方式来传送资料，当想传Ascii 大於128时，常有些问题，因为ASC(Chr(129))=0
，使我们不能用Chr()的指令来放资料。(事实上，您可以使用ChrW(129)来存资料，
和使用AscW()来取得值，加个W代表是Word的运算)，这时候，就只有使用Byte Array
来做了。

1.UniCode转成ByteAry
  Dim byteAry() As Byte
  Dim str5 As String
  Dim i As Long
  str5 = "这abc"
  byteAry = str5
  For i = LBound(byteAry) To UBound(byteAry)
      Debug.Print byteAry(i)   '得 25 144 97 0 98 0 99 0
  Next i
  Debug.Print Len(str5), LenB(str5) '得4  8

  所以了，可看出UniCode 的特性，程式应改一下，使用Strconv()来转换

  Dim byteAry() As Byte
  Dim str5 As String
  Dim i As Long
  str5 = "这abc"
  byteAry = StrConv(str5, vbFromUnicode)
  For i = LBound(byteAry) To UBound(byteAry)
      Debug.Print byteAry(i)   '得 25 144 97 98 99
  Next i
  Debug.Print LenB(StrConv(str5, vbFromUnicode)) '得5

2.ByteAry转回UniCode 使用Strconv()转换
  Dim byteAry(10) as Byte
  Dim Str5 as String
  byteAry(0) = 25
  byteAry(1) = 144
  byteAry(2) = 97
  byteAry(3) = 98
  byteAry(4) = 99
  Str5 = StrConv(byteAry, vbUniCode)


3.一些有用的函式
SubStr()    中文化取子字串，相对Mid()
Strlen()    中文化字串长度，相对Len()
StrLeft()   中文化取左字串，相对Left()
StrRight()  中文化取右字串，相对Right()
isChinese() Check某个字是否中文字

Public Function SubStr(ByVal tstr As String, start As Integer, Optional leng As Variant) As String
Dim tmpstr  As String
If IsMissing(leng) Then
   tmpstr = StrConv(MidB(StrConv(tstr, vbFromUnicode), start), vbUnicode)
Else
   tmpstr = StrConv(MidB(StrConv(tstr, vbFromUnicode), start, leng), vbUnicode)
End If
SubStr = tmpstr
End Function

Public Function Strlen(ByVal tstr As String) As Integer
   Strlen = LenB(StrConv(tstr, vbFromUnicode))
End Function

Public Function StrLeft(ByVal str5 As String, ByVal len5 As Long) As String
Dim tmpstr As String
tmpstr = StrConv(str5, vbFromUnicode)
tmpstr = LeftB(tmpstr, len5)
StrLeft = StrConv(tmpstr, vbUnicode)
End Function

Public Function StrRight(ByVal str5 As String, ByVal len5 As Long) As String
Dim tmpstr As String
tmpstr = StrConv(str5, vbFromUnicode)
tmpstr = RightB(tmpstr, len5)
StrLeft = StrConv(tmpstr, vbUnicode)
End Function

Public Function isChinese(ByVal asciiv As Integer) As Boolean
   If Len(Hex$(asciiv)) > 2 Then
      isChinese = True
   Else
      isChinese = False
   End If
End Function

将阿拉伯数字转成中文字的程式


               一个Form
               一个TextBox
               一个Label

  这个修订後的程式是当使用者在TextBox中输入只包含 0~9 的数值後，在Label中就可
  看见被转换後的中文字，例如：1560890 转成 "壹佰伍拾陆万零捌佰玖拾"。程式限制
  为不可输入超过16个数字。

  请建立一个新专案，并在表单中放入上述物件，再把以下程式码复制到表单的程式
  码视窗，最後按下F5来执行。

  Private Sub Form_Load()
       Text1.MaxLength = 16
       Text1.Text = ""
       Label1.Caption = ""
       Label1.AutoSize = True
       Label1.BorderStyle = 1
  End Sub

  Private Sub Text1_Change()
       Label1.Caption = CChinese(Text1.Text)
  End Sub

  Private Function CChinese(StrEng As String) As String
       If Not IsNumeric(StrEng) Or StrEng Like "*.*" Or StrEng Like "*-*" Then
            If Trim(StrEng) <> "" Then MsgBox "无效的数字"
            CChinese = "": Exit Function
       End If
       Dim intLen As Integer, intCounter As Integer
       Dim strCh As String, strTempCh As String
       Dim strSeqCh1 As String, strSeqCh2 As String
       Dim strEng2Ch As String
       strEng2Ch = "零壹贰叁肆伍陆柒捌玖"
       strSeqCh1 = " 拾佰仟 拾佰仟 拾佰仟 拾佰仟"
       strSeqCh2 = " 万亿兆"
       StrEng = CStr(CDec(StrEng))
       intLen = Len(StrEng)
       For intCounter = 1 To intLen
            strTempCh = Mid(strEng2Ch, Val(Mid(StrEng, intCounter, 1)) + 1, 1)
            If strTempCh = "零" And intLen <> 1 Then
                 If Mid(StrEng, intCounter + 1, 1) = "0" Or (intLen - intCounter + 1) Mod 4 = 1 Then
                      strTempCh = ""
                 End If
            Else
                 strTempCh = strTempCh & Trim(Mid(strSeqCh1, intLen - intCounter + 1, 1))
            End If
            If (intLen - intCounter + 1) Mod 4 = 1 Then
                 strTempCh = strTempCh & Mid(strSeqCh2, (intLen - intCounter + 1) \ 4 + 1, 1)
                 If intCounter > 3 Then
                      If Mid(StrEng, intCounter - 3, 4) = "0000" Then strTempCh = Left(strTempCh, Len(strTempCh) - 1)
                End If
            End If
            strCh = strCh & Trim(strTempCh)
       Next
       CChinese = strCh
  End Function